On *:start: RegisterLink

alias RegisterLink {
  echo -ac info *** Registering IRC URL Handler...
  var %x = rl $+ $ticks
  _regOpen   %x
  $_regWrite(%x, HKCR\irc\Shell\open\ddeexec\,        /ProcessLink % $+ 1)
  $_regWrite(%x, HKCR\irc\Shell\open\ddeexec\ifexec\, /ProcessLink % $+ 1)
  $_regWrite(%x, HKCR\irc\Shell\open\ddeexec\Topic\,  Command)
  _regClose  %x
  echo -ac info *** Done.
}

alias ProcessLink {
  echo -ac info *** Processing IRC URL: $1

  ; Insert your code here. URL is represented as $1
  ;
  ; The URL format is explained in this page:
  ;   http://www.mirc.com/mirclink.html

  ; Pass the URL to mIRC for processing
  dde $ddename Connect "" $1
}

; Registry manipulation aliases
;
; Methods are explained in the Windows Script Host documentation.
alias -l _regOpen  .comopen  $$1 WScript.Shell
alias -l _regClose .comclose $$1
alias -l _regWrite {
  !.echo -q $com($1, RegWrite, 1, bstr, $2, bstr, $$3, bstr, REG_SZ)
}
alias -l _regRead {
  !.echo -q $com($1, RegRead, 1, bstr, $$2)
  return $com($1).result
}
alias -l _regDel {
  !.echo -q $com($1, RegDelete, 1, bstr, $$2)
}